;[InCapture.asm]定时器通道输入捕捉驱动-----------------*
;本文件包含:                                           *  
;    (1)T1Ch0init:定时器1通道0初始化                   *
;硬件连接:                                             *
;    定时器1通道0(PTE2引脚)与扩展板上的一个开关相连    *
;------------------------------------------------------*

;头文件
    INCLUDE 'MC9S08AW60.inc'        ;MCU映像寄存器名

;声明外部函数 
    XDEF   EnableT1Ch0InInt        ;允许定时器1通道0的输入捕捉中断
    XDEF   DisableT1Ch0InInt       ;禁止定时器1通道0的输入捕捉中断
    XDEF   T1Ch0init               ;定时器1通道0初始化
    XDEF   CHFBit                  ;中断使能位宏定义
;宏定义
CHFBit:  equ  7    ;中断标志位
CHIEBit:  equ  6    ;中断使能位

;允许定时器1通道0的输入捕捉中断-------------------------
EnableT1Ch0InInt:
    BSET CHIEBit, TPM1C0SC    
 RTS

;禁止定时器1通道0的输入捕捉中断-------------------------
DisableT1Ch0InInt:
    BCLR CHIEBit, TPM1C0SC    
 RTS
;T1Ch0init:定时器1通道0初始化--------------------------*
;功能:初始化定时器1通道0                               * 
;入口:无                                               *
;出口:无                                               *
;------------------------------------------------------*
T1Ch0init:
    PSHA
    ;1. 设置定时器1状态和控制寄存器
    LDA  #%00010110    
    ;      ||||||||_____分频因子为64
    ;      |||||________不用
    ;      ||||_________定时器复位
    ;      |||__________停止定时器计数
    ;      ||___________禁止定时器溢出中断
    ;      |____________定时器溢出标志位  
    STA  TPM1SC 
    ;2. 设置定时器1通道0状态和控制寄存器
    LDA  #%00001100	   
    ;      ||||||||_____输入捕捉时无用
    ;      ||||||_______跳变沿捕捉
    ;      ||___________禁止输入捕捉中断
    ;      |____________通道标志位
    STA  TPM1C0SC
    PULA
   RTS